Update jsplit, create jgroup command

jsplit now returns the list of created files on stdout
jgroup groups a list of json objects into a dictionary

proofs/psnj_toolbox/bin/dune

 (executable
  (public_name psnj)
  (name main)
- (modules main dopth chainprops appaxiom autosolve qfo split)
+ (modules main dopth chainprops appaxiom autosolve qfo split group)
  (libraries
   ezjsonm
   personoj

proofs/psnj_toolbox/bin/group.ml

+module StrMap = Map.Make (String)
+
+let add (k : string) (o : Ezjsonm.value) (m : Ezjsonm.value list StrMap.t) :
+    Ezjsonm.value list StrMap.t =
+  let objs =
+    match StrMap.find_opt k m with None -> [ o ] | Some objs -> o :: objs
+  in
+  StrMap.add k objs m
+
+let group minify group_by =
+  let groups = ref StrMap.empty in
+  (try
+     while true do
+       let line = input_line stdin in
+       let json : Ezjsonm.value = Ezjsonm.from_string line in
+       let name = Ezjsonm.(find json [ group_by ] |> get_string) in
+       groups := add name json !groups
+     done
+   with End_of_file -> ());
+  let m =
+    StrMap.map List.rev !groups
+    |> StrMap.map (Ezjsonm.list Fun.id)
+    |> StrMap.map Ezjsonm.value
+  in
+  let obj = StrMap.to_seq m |> List.of_seq |> Ezjsonm.dict in
+  Ezjsonm.to_channel ~minify stdout obj
+
+open Cmdliner
+
+let minify = Arg.(value & flag & info [ "m" ])
+
+let group_by =
+  let doc = "Group objects using field $(docv)" in
+  Arg.(value & opt string "name" & info [ "group-by"; "g" ] ~doc ~docv:"FIELD")
+
+let cmd =
+  let doc = "Group JSON objects in arrays depending on a field" in
+  let man =
+    [
+      `S Manpage.s_description;
+      `P
+        "$(tname) is a filter that reads a list of JSON objects and group them \
+         in a dictionary. Groups are determined by the value of a name (which \
+         is-confusingly-$(b,name) by default). The values associated to this \
+         name become the keys of the dictionary.";
+      `S Manpage.s_examples;
+      `P "Given JSON objects";
+      `Pre
+        {|{ "name": "foo", "attr": "baz"   }
+{ "name": "bar", "attr": "frobz" }
+{ "name": "foo", "attr": "nitz"  }|};
+      `P "The output of $(tname) -g name is";
+      `Pre
+        {|{
+    "bar": [
+      {
+        "name": "bar",
+        "attr": "frobz"
+      }
+    ],
+    "foo": [
+      {
+        "name": "foo",
+        "attr": "nitz"
+      },
+      {
+        "name": "foo",
+        "attr": "baz"
+      }
+    ]
+  }|};
+    ]
+  in
+  (Term.(const group $ minify $ group_by), Term.info "jgroup" ~doc ~man)

proofs/psnj_toolbox/bin/main.ml

@@ -6,6 +6,14 @@ let default_cmd =
   (Term.(ret @@ const @@ `Help (`Pager, None)), Term.info "psnj" ~doc ~exits)
 
 let cmds =
-  [ Dopth.cmd; Chainprops.cmd; Appaxiom.cmd; Autosolve.cmd; Qfo.cmd; Split.cmd ]
+  [
+    Dopth.cmd;
+    Chainprops.cmd;
+    Appaxiom.cmd;
+    Autosolve.cmd;
+    Qfo.cmd;
+    Split.cmd;
+    Group.cmd;
+  ]
 
 let () = Term.(exit @@ eval_choice default_cmd cmds)

proofs/psnj_toolbox/bin/split.ml

 let split prefix =
+  let fnames = ref [] in
   try
     while true do
       let line = input_line stdin in
       let json = Ezjsonm.from_string line in
       let name = Ezjsonm.(find json [ "name" ] |> get_string) in
-      let fname = String.concat "_" [ prefix; name ] in
+      let fname = String.concat "_" [ prefix; name ] ^ ".json" in
+      fnames := fname :: !fnames;
       let oc = open_out fname in
       at_exit (fun () -> close_out oc);
       output_string oc line;
       output_char oc '\n'
     done
-  with End_of_file -> ()
+  with End_of_file ->
+    List.(iter (Format.printf "%s@\n") (sort_uniq String.compare !fnames))
 
 open Cmdliner
 
@@ -28,7 +31,8 @@ let cmd =
         "$(tname) reads a newline-seprated list of json objects on its \
          standard input and copies each object to a file $(i,pr)_$(i,n).json \
          where $(i,n) is the value associated to the (json) name $(b,name) and \
-         $(i,pr) is a chosen prefix.";
+         $(i,pr) is a chosen prefix. The list of created files is returned on \
+         standard output. Files appear at most once in the list.";
       `S Manpage.s_examples;
       `P "Faced with input";
       `Pre

proofs/psnj_toolbox/test/jgroup/dune

+(cram
+ (deps input.json))

proofs/psnj_toolbox/test/jgroup/input.json

+{ "name": "foo", "attr": "baz"   }
+{ "name": "bar", "attr": "frobz" }
+{ "name": "foo", "attr": "nitz"  }

proofs/psnj_toolbox/test/jgroup/jgroup.t

+  $ psnj jgroup < input.json
+  {
+    "bar": [
+      {
+        "name": "bar",
+        "attr": "frobz"
+      }
+    ],
+    "foo": [
+      {
+        "name": "foo",
+        "attr": "baz"
+      },
+      {
+        "name": "foo",
+        "attr": "nitz"
+      }
+    ]
+  }

proofs/psnj_toolbox/test/jsplit/jsplit.t

-  $ psnj jsplit -p ff < input.json; find . -type f -printf "\n%p\n" -exec cat {} \;
+  $ psnj jsplit -p ff < input.json
+  ff_bar.json
+  ff_foo.json
+
+  $ find . -type f -printf "\n%p\n" -exec cat {} \;
   
-  ./ff_bar
-  { "name": "bar", "attr": "frobz" }
-  
-  ./ff_foo
+  ./ff_foo.json
   { "name": "foo", "attr": "baz"   }
+  
+  ./ff_bar.json
+  { "name": "bar", "attr": "frobz" }